**********************************************************
*
* BCM53DS
*
* Nexperia
*
* Matched double PNP/PNP transistors
* IC   = 1 A
* VCEO = 80 V 
* hFE  = 63 - 250 @ 2V/150mA
*
*
*
*
* Package pinning does not match Spice model pinning.
* Package: SOT 457
* 
* Package Pin 1;2: Base		TR1;TR2
* Package Pin 6;3: Collector	TR1;TR2
* Package Pin 5;4: Emitter 	TR1;TR2
*
*
* Extraction date (week/year): 18/2016
* Spicemodel includes temperature dependency
*
**********************************************************
*#
* Please note: The following model is to be used twice in 
* schematic due to equality of both transistors.
*
* Diode D1, Transistor Q2 and Resistor RQ 
* are dedicated to improve modeling of quasi
* saturation area and reverse mode operation
* and do not reflect physical devices.
*
.SUBCKT BCM53DS 1 2 3
Q1 1 2 3 MAIN 0.7
Q2 11 2 3 MAIN 0.3
RQ 1 11 9
D1 1 2 DIODE
*
.MODEL MAIN PNP
+ IS = 4E-014
+ NF = 0.9996
+ ISE = 1E-015
+ NE = 1.3
+ BF = 165
+ IKF = 0.6718
+ VAF = 28.34
+ NR = 0.9982
+ ISC = 1.406E-014
+ NC = 1.325
+ BR = 11.84
+ IKR = 0.86
+ VAR = 80
+ RB = 10
+ IRB = 0.001
+ RBM = 2.5
+ RE = 0.0911
+ RC = 0.04295
+ XTB = 1.723
+ EG = 1.11
+ XTI = 9.039
+ CJE = 6.777E-011
+ VJE = 0.7404
+ MJE = 0.3651
+ TF = 1.077E-009
+ XTF = 1.587
+ VTF = 2.697
+ ITF = 0.7421
+ PTF = 0
+ CJC = 2.816E-011
+ VJC = 0.4549
+ MJC = 0.3035
+ XCJC = 1
+ TR = 8E-008
+ CJS = 0
+ VJS = 0.75
+ MJS = 0.333
+ FC = 0.8944
.MODEL DIODE D
+ IS = 6.593E-016
+ N = 0.9582
+ BV = 1000
+ IBV = 0.001
+ RS = 838.6
+ CJO = 0
+ VJ = 1
+ M = 0.5
+ FC = 0
+ TT = 0
+ EG = 1.11
+ XTI = 3
.ENDS
*