*Model BUK9620-55A
*N.B prepared by MC 16/2/05 assumes 2 source wires and 1 gate wire, wires are made of aluminium.

.SUBCKT BUK9620-55A D G S 
X1 S 5 bondwire params: length=4m dia=350u
X2 S 5 bondwire params: length=4m dia=350u
X3 G 1 bondwire params: length=4m dia=125u
Rg 1 4 0.7
Rdgd 2 3 1e9  
Rcgd 3 4 1e9  
Rcgs 4 5 1e8
Dgd 3 2 Dgd 
Cgd 3 4 1.8E-09
Cgs 4 5 1.47E-09
M1 2 4 5 5 Mint           
M2 4 2 3 3 Mdg
Rd 2 D Rtemp1 6.9e-3
Dsd 5 6 Dsd
Rdsd 6 D Rtemp1 0.1e-3
Rlsd 5 D Rtemp2 2.75E+11 
.MODEL Mint NMOS(Vto=1.75 Kp=36 Nfs=1e11 Eta=1e3
+ Level=3 L=1e-4 W=1e-4 Gamma=0 Phi=0.6  Is=1e-24
+ Js=0 Pb=0.8  Cj=0 Cjsw=0 Cgso=0 Cgdo=0 Cgbo=0
+ Tox=1e-7 Xj=0 
+ U0=0           
.MODEL Dsd D(Bv=64 Ibv=250e-6 Rs=6.1e-3 Is=6.02e-11
+ N=1 M=0.5 VJ=1 Fc=0.5 Cjo=4.9e-10 Tt=33e-9)
.MODEL Dgd D(Cjo=9.89e-10 Rs=1e-3
+ Is=1e-14 M=0.4 N=1 VJ=1 Fc=0.5)
.MODEL Mdg NMOS(Vto=1e-3 Kp=10 Nfs=0 Eta=0
+ Level=3 L=1e-4 W=1e-4 Gamma=0 Phi=0.6  Is=1e-24
+ Js=0 Pb=0.8  Cj=0 Cjsw=0 Cgso=0 Cgdo=0 Cgbo=0
+ Tox=1e-7 Xj=0 
+ U0=0 )          
.MODEL Rtemp1 RES(TC1=5.16e-3)
.MODEL Rtemp2 RES(TC1=-0.005)
.ENDS 

.SUBCKT bondwire 1 3 params: length=1m dia=1u
L1 1 2 {2*length*(log(4*length/dia)-1)*1e-7}
R1 2 3 {length*2.8e-8/(3.1415*(dia/2)^2)}
R2 1 2 {(2*length*(log(4*length/dia)-1)*1e-7)*2*3.1415*50e6}
.ENDS